Arco Iris 9.999

Este es el último indicador salido de la «Factoría Paquete» y aunque en el futuro habrá más, con éste terminamos la serie de lo que es necesario para operar el sistema o más bien de los indicadores auxiliares que yo utilizo para operar el sistema. Obviamente, los indicadores de amplitud, de los que poco hemos hablado hasta el momento, son la otra pata del sistema.

Arco Iris 9.999 es también un indicador complejo y lo primero que hay que decir de él es que para que funciones debéis tener descargado a la plataforma Gatillo 7.0 y llamarlo exactamente por ese nombre, con espacio incluido. Parte de las cosas que hace Arco Iris están basadas en configuraciones específicas de Gatillo y no he reformulado el indicador hasta el punto tal que no sea necesario llamar a Gatillo. Hubiera tenido un código kilométrico.

Además de estas configuraciones positivas de Gatillo, en Arco Iris se reflejan relaciones de capital climático, configuraciones positivas de RSI y E-RSI, entrada de mano fuerte, existencia o no de fuerza en el valor medida por Bull/Bear e incluso buscamos un determinado aumento de volumen «weinsteiniano», que se produce cuando en el indicador aparece el color rojo.

Ni qué decir tiene que se trata de un indicador que sólo es utilizable en tendencias alcistas y que estoy desarrollando Arco Iris 10.0 que también será aplicable a las tendencias bajistas, pero me va a llevar algún tiempo.

Veamos el indicador y qué buscamos en él. Lo mejor es poner un grafico para seguir la explicación:

apple y Artco Iris 9o.,99

La idea con la que desarrollé este indicador es la de tener un «chivato» para las rupturas de resistencias importantes. Si el valor no saca en la ruptura (no hace falta que sea en el mismo día, pero sí  al menos en cuatro o cinco anteriores o posteriores) al menos color azul, la ruptura tiene grandes posibilidades de ser un engañabobos. En cambio, en el gráfico vemos como tiene la curiosa costumbre de que las estrellas se alineen cuando las rupturas van a ser buenas.

No es casualidad que la mano fuerte, la fuerza del valor y el volumen confluyan en una zona y este indicador detecta exactamente eso. Si además sabemos en qué zonas debe pasar eso, tenemos un indicador estupendo para validar rupturas. Recuerdo que este indicador en su versión semanal nos evitó un serio contratiempo en un valor alemán, Infineon, que al romper no sacó colores, lo que nos hizo anular la entrada. La ruptura resultó un engaño y el valor se desplomó.

Pero no es esa su única función. A lo largo de una tendencia alcista, el valor debe ir mostrando momentos de calentamiento y otros de relajación. Los recalentamientos demasiado prolongados deben llevarnos a desconfiar. Cuantos más colores enseñe el indicador, y tiene el arco iris completo, más recalentado está y la desaparición súbita de colores debe infundirnos desconfianza.

Complementariamente, junto al Semáforo Alcista, configura un método excelente para buscar valores «adelantados» a la recuperación de los índices. Basta con hacer que un proscreener busque valores con verde en el semáforo alcista y azul en el Arco Iris en momentos en los que el mercado ha intentado recuperar pero no lo ha conseguido. El momento ideal es el «antes», pero para el después podemos buscar incluso valores que estaban positivos mientras sus índices hacían mínimos, que los hay. Mayor fuerza que eso no es fácil encontrar.

Aquí os dejo el código (corregido después de haber encontrado un error que fue explicado en este post):

REM INDICADOR PAQUETE ARCO IRIS 9.999 DIARIO
REM BY PAQUETE TRADER 2012
REM ES NECESARIO TENER INSTALADO
REM EL INDICADOR GATILLO 7.0 LLAMADO
REM EXACTAMENTE POR ESTE NOMBRE
REM LA CONFIGURACION DE COLORES VA "DE SERIE"
REM SOLO HAY QUE PEDIRLE QUE LO REPRESENTE
REM COMO HISTOGRAMA
REM LLAMADAS A INDICADORES
IGNORED, IGNORED, IGNORED, ignored, FILTRO,VIGIA, GATILLO, PICO = CALL "GATILLO 7.0"
REM VAMOS A INTRODUCIR EL CONCEPTO CAPITAL MEDIO
capital = volume * close
volmax = highest[200](capital)
vol = ((capital*100/volmax)*4/5)
volmed = ExponentialAverage[50](vol)
cpm = (vol - volmed)
REM INTRODUCIMOS UNA VERSION RAQUÍTICA DE KONKORDE
REM PARA BUSCAR LA MANO FUERTE
nvi =NegativeVolumeIndex(close)
nvim = ExponentialAverage[15](nvi)
nvimax = highest[90](nvim)
nvimin = lowest[90](nvim)
lazul = (nvi - nvim) * 100/ (nvimax - nvimin)
REM INTRODUCIMOS EL E-RSI19/39
REM EN VERSIÓN SIMPLIFICADA
oscilador = (RSI[19](close) - lowest[39](RSI[19](close))) / ( highest[39](RSI[19](close)) - lowest[39](RSI[19](close)))
REM INTRODUCIMOS BULL/BEAR EN VERSION SIMPLIFICADA
FUERZA = (EXPONENTIALAVERAGE[19](CLOSE)/CLOSE)-(EXPONENTIALAVERAGE[39](CLOSE)/CLOSE)
REM VARIABLES INTRODUCIDAS
FILTRADO = (OSCILADOR > 0.50 AND gatillo > gatillo[1] AND vigia > 0)
POSITIVO = VIGIA > FILTRO AND (PICO > 0 or vigia > 50)
GATILLOBLANCO = GATILLO > 15 AND PICO > 5 AND VIGIA > 30
MANOFUERTE = LAZUL > 10
MASFUERZA = FUERZA > 0.5 AND FUERZA > FUERZA[1]
RSIVALE = RSI[9](CLOSE) > RSI[9](CLOSE)[1]
FUERTE = close > average[21] and weightedaverage[150](close) > weightedaverage[150](close)[1] and fuerza > fuerza[1] and fuerza > 0
VOLUMEN1 = CAPITAL / (AVERAGE[20](CAPITAL)[1]) > 2 AND CPM > 0
VOLUMEN2 =(CPM > CPM[1] AND CPM > -5) OR (CPM > -2 AND CPM[1]>0) OR VOLUMEN1
REM CONDICIONES
REM PRIMERA CONDICION: QUE EL FILTRADO DE GATILLO Y E-RSI SEA POSITIVO
C1 = FILTRADO
REM SEGUNDA CONDICION: QUE LA CONFIGURACIÓN DE GATILLO SEA POSITIVA
C2 = C1 AND POSITIVO
REM TERCERA CONDICION: QUE, ADEMAS, EL RSI DE NUEVE PERIODOS SEA ASCENDENTE
C3 = C2 AND RSIVALE
REM CUARTA CONDICION: QUE EL VOLUMEN CLIMÁTICO SEA POSITIVO Y EL VALOR TENGA FUERZA
C4 = C3 AND FUERTE AND VOLUMEN2
REM QUINTA CONDICION: QUE LA MANO FUERTE EN KONCORDE SIGA AL ALZA
C5 = C4 AND MANOFUERTE
REM SEXTA CONDICION: QUE ADEMÁS GATILLO ESTÉ MOSTRANDO BLANCO O BULL/BEAR SEA "COMODAMENTE" ALCISTA
C6 = C5 AND (GATILLOBLANCO OR MASFUERZA)
REM SEPTIMA: BUSCAREMOS EL VOLUMEN WEINSTEINIANO, AUNQUE ESTA ES INDEPENDIENTE DE LAS DEMAS Y SE MUESTRA LA MAS PEQUEÑA EN ROJO
C7 = VOLUMEN1
REM COMBINACIONES
IF C1 THEN
FUGA1 = 1
ELSE
FUGA1=0
ENDIF
IF C2 THEN
FUGA2 = 1.5
ELSE
FUGA2=0
ENDIF
IF C3 THEN
FUGA3 = 2
ELSE
FUGA3 =0
ENDIF
IF C4 THEN
FUGA4 = 2.5
ELSE
FUGA4 = 0
ENDIF
IF C5 THEN
FUGA5 = 3
ELSE
FUGA5=0
ENDIF
IF C6 THEN
FUGA6 = 3.5
ELSE
FUGA6 = 0
ENDIF
IF C7 THEN
VOLUMEN = 0.5
ELSE
VOLUMEN = 0
ENDIF
RETURN FUGA6 coloured(255,55,255) AS "FUGA6", FUGA5 coloured (55,0,255) AS "FUGA5", FUGA4 coloured(0,255,255) AS "FUGA4", FUGA3 coloured(0,255,0) AS "FUGA3", FUGA2 COLOURED (255,255,0) AS "FUGA2", FUGA1 COLOURED (255,175,0) AS "FUGA1", VOLUMEN COLOURED (255,0,0) AS "VOLUMEN", 0 AS "CERO"

Como siempre, espero que os guste. Felices plusvalías.

¿Lo compartes?

28 comentarios en «Arco Iris 9.999»

  1. Hola a todos!!!
    Alguien tiene la programación para prorealtime para las siguientes condiciones?

    1.- Semáforo Alcista = VERDE
    2.- Arco Iris 9.99 = AZUL
    3.- WMM150 Alcista
    4.- Mano Fuerte dentro.
    5.- Capitalización > 1.000.000
    6.- Ordenados por Bull/Bear Alcista

    Lo agradecería mucho!!! por supuesto, a los maestros más todavía!

  2. Es el screener q puso en comentarios anteriores txename. Copie los códigos tal cual lo puse en prosecree el en prorealtime y cuando le doy validar me genera ese error. Yo tengo el libro de ustedes pero no encuentro q screener usan ustedes en prorealtime saludos

    • En el libro no se publica ningún código de screeners. Cada momento tiene su búsqueda y muchas veces es necesario crear un screener para cada momento. En cualquier caso, los screeners de PRT son muy limitados en su versión básica. Respecto al publicado en comentarios anteriores por Txemame, creo recordar de él que usaba la mano fuerte del indicador Koncorde de Blai5 para uno de los cálculos así que tendrás que cargarlo en la plataforma si quieres que te funcione. Si lo tienes cargado, el error estará en que Txemame llama al indicador de una manera «M.T. Semaforo alcista» y en tu base de datos se llama de otra. O cambias el código del screener para adaptarlo a tu nombre o cambias el nombre para adaptarlo al código, pero si el código llama a un nombre que no existe nombre no funcionará. Y cuando hayas hecho eso con el Semáforo Alcista, te quedarán todos los demás para corregir.

  3. Hola tengo cargado los indicadores de ustedes en prorealtime y se ven igual al de ustedes pero cuando cargó el screener de market timing selectivo le voy a dar validar y me sale error «m.t semáforo alcista » llamado desde market timing selectivo » no existe.
    Tienen idea q puedo estar haciendo mal¿… Muchas gracias y saludos

    • Perdona Juan pero yo no trabajo con PRT. Miguel vuelve mañana de vacaciones y el te dirá qué puedes hacer-

    • Me vas a perdonar que te responda con una pregunta. ¿Qué es el screener de Market Timing selectivo?

  4. Muchas gracias por tu comentario, me anima a seguir mejorando.
    El nivel de esta web se va poniendo altísimo y las aportaciones de los participantes son cada vez más interesantes.
    Me alegro mucho de la gran acogida que estais teniendo.
    Saludos de Txema

  5. A falta de hacer pruebas, a mí me gusta lo que vas haciendo. Es mjy exigente todo lo que pides

  6. Estoy intentando añadir algunas variables al Screener Market Timing para que la selección de valores sea más reducida.
    Estas son las condiciones:
    1.- Semáforo Alcista = VERDE
    2.- Arco Iris 9.99 = AZUL
    3.- WMM150 Alcista
    4.- Mano Fuerte dentro.
    5.- Capitalización > 1.000.000
    6.- Ordenados por Bull/Bear Alcista

    Como se trata de hacer pruebas me gustaría contar con opiniones y mejoras si algún entendido en programación en PRT se anima.
    Saludos de Txema
    REM SCREENER MARKET TIMING SELECTIVO
    REM Semáforo en Verde
    indicator1, ignored, ignored, ignored = CALL «M.T. – Semáforo Alcista»
    c1 = (indicator1 = 3.0)

    REM Arco Iris en Azul
    ignored, ignored, indicator2, ignored, ignored, ignored, ignored, ignored = CALL «M.T.-Paquete Arco Iris 9.99″(close)
    c2 = (indicator2 = 2.5)

    REM Citerio de ordenación: Bull/ Bear: Fuerza Alcista > 0.5
    ignored, criteria, ignored, ignored = CALL «M.T. – Bull / Bear»

    REM WMM150 Alcista
    indicator3 = WeightedAverage[150](close)
    indicator4 = WeightedAverage[150](close)
    c3 = (indicator3 > indicator4[1])

    REM Mano Fuerte dentro
    ignored, ignored, ignored, ignored, ignored, azul, ignored, ignored = CALL «Blai5 Koncorde v.09″[15]
    c4 = (azul > 0)

    REM Capitalización
    cap = close*volume
    c5 = cap > 1000000

    SCREENER[c1 AND c2 AND c3 AND c4 AND c5] (criteria AS «UP»)

  7. Esto cada vez está mucho mejor. Magníficos los indicadores. Los estoy probando y dan en el clavo por ejemplo con SAN(fra), DPS, CVS, …
    Siguiendo vuestras indicaciones para crear un screener buscador, Semáforo Alcista VERDE y Arco Iris AZUL, he creado este screener. A ver que os parece y si es suficiente para la operativa. Si proponeis otro más sofisticado, pues la releche.

    REM SCREENER MARKET TIMING
    indicator1, ignored, ignored, ignored = CALL «Semáforo Alcista»
    c1 = (indicator1 = 3.0)
    ignored, ignored, indicator2, ignored, ignored, ignored, ignored, ignored = CALL «Paquete Arco Iris 9.999″(close)
    c2 = (indicator2 = 2.5)
    ignored, criteria, ignored, ignored = CALL «Bull / Bear»
    SCREENER[c1 AND c2] (criteria AS «UP»)

    Saludos y muchas gracias

    • Hola txemame,
      Una pregunta. He visto que estabas probando en el 2012 el screener con las condiciones siguientes:
      1.- Semáforo Alcista = VERDE
      2.- Arco Iris 9.99 = AZUL
      3.- WMM150 Alcista
      4.- Mano Fuerte dentro.
      5.- Capitalización > 1.000.000
      6.- Ordenados por Bull/Bear Alcista

      Lo llegaste a pulir? te funciona? te importaría pasármelo? te lo agradecería mucho.
      Saludos.

    • Hola Txename,
      Estoy intentando poner tu screener pero no lo consigo. Qué crees que puede fallar??? lo has mejorado? gracias!

    • La selección de valores no se hace en el día de los mínimos de los índices, sino en el último momento anterior en el que los índices intentaron la remontada y que nosotros conocemos como «antes». En este caso se produjo en los entornos del día 23 de mayo. Te pongo Suedzucker y seguimos viendo:
      Arco Iris - Suedzucker
      Como se puede apreciar, había azul cuando lo buscábamos, lo que significa que el valor tenía fuerza cuando su índice aún no la tenía y eso es un indicio de que será de los que salga escopetado cuando todo esté preparado. Tras la entrada, tenía que superar una resistencia, y lo ha hecho limpiamente y sacando colorines así que ha superado la prueba y estamos dentro tan tranquilos. Para eso sirve Arco Iris. Si no hubiera sacado colores, mala cosa.
      En cambio, si buscas en Inditex verás que sus últimos colores datan de abril, en el intento anterior de los índices por salir del pozo. Técnicas Reunidas, en cambio, tiene colorines en torno al 23 de mayo. Elegí Inditex porque es el único valor realmente fuerte del Ibex y porque abril era una buena fecha para sacar colores (fíjate que Suedsucker también tenía colores en esas fechas). El sistema de búsquedas es algo más «personal» y lo iremos explicando poco a poco. Ángel elige los americanos y yo los europeos y lo hacemos por métodos distintos, como casi todo en este blog, para demostrar que se puede llegar a los mismos resultados por distintos sitios aplicando la misma filosofía.

      • Buenos días,

        ¿Entonces ahora deberíamos buscar valores que daban las señales en el último tramo alcista antes de la corrección?
        ¿Se puede buscar en PRT referenciándolo a una fecha anterior?

        Muchas gracias por vuestras aportaciones.

        • Buenas noches. Miguel está de vacaciones.

          No uso PRT, quizás te pueda ayudar alguien de los usuarios de Pro Real Time. Cuando intenté trabajar con ellos no tenían indicadores de amplitud de mercado y los dos que tenían estaban mal calculados. Nosotros los obtenemos por Metastock u hoja de cálculo.

          El sincronismo (Market Timing) tiene dos aspectos: el interno, que se da entre componentes y su índice y el externo que se funda en que los mercados suelen efectuar sus giros en los dos sentidos en las mismas fechas o con escasas diferencias.
          Una vez que hemos decidido abrir posiciones largas en el mercado más fuerte (Nasdaq/NYSE), deberíamos esperar a que llegaran los puntos de sincronismo, para entrar o para piramidar o añadir posiciones.
          El próximo que esperamos sera el último de los tres de cada gran corrección, y debería llegar en este mes de julio tras una fuerte corrección, detectaremos el día del giro y daremos la señal y los valores líderes en los que nosotros abriremos posiciones.

          Nuestra cartera de valores líderes de los dos puntos de sincronismo anteriores la puedes ver en los apartados de esta web: Cartera y/o valores.

          Puedes revisar las revalorizaciones tu mismo, desde sus mínimos de primeros de junio día 4, o desde el 18 de mayo, los días de las señales fueron el día 21 de mayo y creo que el día 6 de mayo. Lo puedes comprobar seleccionando los post desde el calendario del «Home».

          • Interrumpo mis vacaciones durante cinco minutos para contestar a esto, que me parece muy importante y no se pueden dejar dudas.
            PRT se puede referenciar a fechas anteriores, hasta 250 días para atrás en la versión gratuita.
            Pero no vale lo del «último tramo alcista antes de la corrección». Buscamos siempre en el «antes» o en el «durante». En un momento dado todos los valores de un índice pueden ser alcistas después de un buen tramo al alza, así que no vale cualquier selección en cualquier momento. Market timing es exactamente eso, buscar la sincronización con el mercado en el valor oportuno y el momento oportuno.

  8. Hola Miguel, buenas noches.

    Gracias por el codigo. Una pregunta, esta instalado y va perfectamente. La pregunta es referente a las señales, por ejemplo en la «cartera Europea» he mirado un par de ellas por curiosidad (SUEDZUCKER e Inditex) y ninguna de ellas tiene azul en el arco iris. En el cso de SUEDZUCKER solo naranja y en Inditex, nada.
    COmo se interpreta esto?

    GRacias